Changing bits while cutting a Part File

[ShopBot]

THREAD FROM ARCHIVE
================================================== ====
From: PeteB Date: 24 Jan 1999

Can I change router bits in the middle of cuttin a file without screwing up my 0,0,0 settings?


From: Bruce Clark Date: 24 Jan 1999

Here's a sample file showing one technique for doing bit changes:

'Tool Change Routine
'loads ShopBot variable &x, &y, &z with shopbot registers
&X=%(1)
&Y=%(2)
&Z=%(3)
'Return to the Home position (0,0)
JH
PAUSE 'Turn OFF router and change bit--Press any key to continue
'Return to current position
J2,&X,&Y
JZ,&Y


From: RP Date: 25 Jan 1999

As it is probably impossible to place your new bit at the exact same height as the first one, you will have to re-set the z axis position. The zzero routine from Ted Hall makes this easy. You can download it from ShopBot's web page (download section)

[supertigre]

To add an "Armstrong" tool changer to your 'bot
include the following code at the beginning of
your .sbp file. Most of this is Ted's Z Zero routine.

NOTE REQUIRES Z SWITCH!!!!

NOTE after adding this code the .SBP file WILL NOT RUN in preview mode!!!

goto Start_Cutting
Change_tool:
JZ,3
J2,1,1
SA,
SF,0
SC,0
&ZBOT=0.125 '<--- the thickness of your Z switch
&ZUP=.5
ON INP(1,1) GOSUB CONTACT
PAUSE
MZ, -5
' *** Zeroing routine complete, Hit ENTER to continue ***'
PAUSE
SC,1
RETURN
CONTACT:
ON INP(1,1)
VA,,,&ZBOT
JZ, &ZUP
RETURN
Start_Cutting:

Each time you want to change your tool in the .SBP file insert the following.

' *** Spildle off, Change to Tool '?????????????' and Hit ENTER to Zero on plate ***'
gosub Change_tool

[kerrazy]

Guy,
Could you please give me a file from start to finish with two or three tool changes, so I can grasp where to put these lines of code. You do not need tons of m2 moves jast a not so i can get a better understanding as to how this will work.
Thanks,
Dale

[supertigre]

Dale;

Here is a short sample. It allows you to change the tooling in the middle of a .SBP file without losing your current (0,0) position. Just remember to turn your router off and on at the appropriate places!

Use at your own risk, not valid on Tuesdays, Thursdays, or Bank Holidays, slippery when wet, contains user servicable parts, your mileage will vary, 10% discount for seniors and left handed men with red hair on Wednesdays only (Woodrow Wilson Smith excluded - he pays double!), offer valid only OUTSIDE of the United States of America and Nigeria, liability limited to the original purchase price less 2 cents for shipping and handling. Consulting services are available at ShopBot's posted rates when paid in advance. Half a mice dya. :P

goto Start_Cutting
Change_tool:
JZ,3
J2,1,1
SA,
SF,0
SC,0
&ZBOT=0.125
ON INP(1,1) GOSUB CONTACT
PAUSE
MZ, -5
' *** Zeroing routine complete, Hit ENTER to continue ***'
PAUSE
SC,1
RETURN
CONTACT:
ON INP(1,1)
VA,,,&ZBOT
JZ,0.5
RETURN
Start_Cutting:
' *** Change to Tool '45 Deg V X .375' and Hit ENTER to Zero on plate ***'
gosub Change_tool
J3,4.45421314,6.72791767,0.5
M3,4.45421314,6.72791767,0
M3, 4.46943474, 6.74097729, -0.0367484
M3, 4.47002363, 6.74152803, -0.03816941
' *** Change to Tool '3/8 Flat X 1' and Hit ENTER to Zero on plate ***'
gosub Change_tool
J3,2.51063466,6.82251406,0.5
M3,2.51063466,6.82251406,-0.51999998
CG,,2.33207226,6.63517332,-3.5042,3.1612,,1
M3, 2.33085585, 6.63397264, -0.51999998
M3, 2.32629466, 6.62948322, -0.51999998
JZ,3
J2,40,20
END

[robtown]

is it possible to use #include (or eq.) and have this as a separate file?

Then all you'd have to do to your cutting files is put the sub_routine calls in the appropriate places...

[supertigre]

Yes, but you still have to edit the .SBP file to add the tool change requests and it still won't run in preview mode.

There are 53 different ways to skin a cat, but none of them are any better for the cat than the other 52.

[robtown]

k
I was really more after how to do it, I wasn't commenting one way or the other on the best way to implement it...

[beacon14]

If you use Rob's idea and make the bit change as a separate file, then make another dummy file that does nothing, you can swap the names of the "bit-change" file and the "nothing" file temporarily, allowing you to view the original file in preview mode without having to edit it first.

Or, you could add a line at the beginning of "bit-change.sbp" that says something like GOTO END, then comment that line out for the actual cutting. Either way would be easier than having to comment out each instance of bit-changing in the main file.

It's not the cat we're worried about here, it's the skinner who has to make a living. The cat's a goner any way you look at it.

[supertigre]

Or to take this one step further.

Most people have two computers, one for design and another for driving the 'Bot. Put the dummy routine on the design machine (to allow preview) and the real routine on the 'Bot driver. You will have to nail the routine into a fixed folder on both machines so that you can run files from different drives / folders. Wrx 4 me. Thnx